scoreboard players set @s scientist.laser.min 30
execute as @e[type=interaction,tag=study.capsule] on passengers unless items entity @s container.0 air run function ws:work/misc/tier2/scientist/modifystudylasermin with entity @s item.components."minecraft:custom_data".modifiers[]
execute at @n[tag=blue_laser,type=item_display,scores={laser.rotation=1}] run playsound minecraft:block.amethyst_block.hit player @a ~ ~ ~ 3.5 2
execute at @n[tag=blue_laser,type=item_display] run particle minecraft:sculk_charge_pop ~ ~ ~ 0 0.1 2.1 0 2 normal
particle enchant ~ ~ ~ 1.5 1.5 1.5 0 10
scoreboard players add @s meteorite.study 1
execute unless score @s meteorite.study >= @s scientist.laser.min run return 0
function ws:work/misc/tier2/scientist/studymeteorite
playsound minecraft:block.sculk.charge player @a ~ ~ ~ 3 0
particle sculk_charge_pop ~ ~ ~ 1.5 1.5 1.5 0 300
execute as @e[type=interaction,tag=study.capsule] on passengers run function ws:work/misc/tier2/scientist/usecapsule
scoreboard players reset @s meteorite.study