execute unless items entity @s armor.* *[minecraft:custom_data~{chef:1}] run return run function ws:work/join/fail {work:chef}
execute store result score .chef chef.players if entity @a[team=povar]
execute if score .chef chef.players matches 2.. run return run function ws:work/join/fail.player {work:chef}
team join povar @s
recipe give @s *
execute unless score @s starterbonus.chef matches -3.. run scoreboard players set @s starterbonus.chef 10
tellraw @s[scores={starterbonus.chef=1..}] [{"translate":"starterbonus.active","color":"green"},{"translate":"starterbonus.chef"},{"translate":"starterbonus.left"},{"score":{"name":"*","objective":"starterbonus.chef"}},{"translate":"starterbonus.left2"}]
tp @s 2080.675 42 2019.5 0 0
execute if score .chef chef.players matches 0 as @e[tag=chef.display,type=minecraft:item_display] run function ws:work/misc/chef/random
execute at @s[scores={starterbonus.chef=1..}] run playsound minecraft:entity.player.levelup player @s ~ ~ ~ 1 2