execute unless score @s weight.level matches 6.. run return run function ws:item/return_soldier_syringe
execute at @s run playsound minecraft:entity.player.levelup player @s ~ ~ ~ 0.5 1.5
tellraw @s {"translate":"unishop.item.soldier_syringe.levelup","color":"dark_green"}
scoreboard players remove @s stat.strength 5
scoreboard players remove @s weight.level 5
execute store result storage ws:temp stats.amount float 0.05 run scoreboard players get @s stat.strength
data modify storage ws:temp stats.attribute_type set value 'generic.attack_damage'
data modify storage ws:temp stats.operation set value 'add_multiplied_total'
function ws:misc/stats/update with storage ws:temp stats
scoreboard players add @s stat.soldier_syringe 1
execute store result storage ws:temp stats.amount float 0.4 run scoreboard players get @s stat.soldier_syringe
data modify storage ws:temp stats.attribute_type set value 'generic.attack_speed'
data modify storage ws:temp stats.operation set value 'add_value'
function ws:misc/stats/update with storage ws:temp stats