execute unless data storage funkalot:tracks tracks.difficulty run function funkalot:tracks/difficulty/select/normal
execute if score @s left.press matches 1 run function funkalot:tracks/difficulty/decrease
execute if score @s right.press matches 1 run function funkalot:tracks/difficulty/increase
execute if score @s up.press matches 1 run function funkalot:tracks/up
execute if score @s down.press matches 1 run function funkalot:tracks/down
execute if score @s sprint.press matches 1 run return run function funkalot:tracks/tostart
execute if score @s space.press matches 1 run function funkalot:tracks/choose with storage funkalot:tracks tracks
function funkalot:scroll
scoreboard players add .trackswait constants 1
execute unless score .trackswait constants matches 200.. run return 0
execute store result storage funkalot:tracks tracks.tracksnumber int 1 store result score .tracksnumber constants if data storage funkalot:tracks tracks.list[]
scoreboard players operation .trackspagesnumber constants = .tracksnumber constants
scoreboard players operation .trackspagesnumber constants /= .3 constants
scoreboard players operation .tracksnumber constants %= .3 constants
execute if score .tracksnumber constants matches 0 run scoreboard players remove .trackspagesnumber constants 1
data merge entity @n[tag=tracks.navigation] {text:[{"text":""}]}
data merge entity @n[tag=tracks.navigation] {text:[{"translate":"tracks.navigation","with":[{"keybind":"key.forward"},{"keybind":"key.back"},{"keybind":"key.jump","color":"green"},{"keybind":"key.left"},{"keybind":"key.right"},{"keybind":"key.sprint"}]}]}