#knockback stop
function main:mechanics/knockback_stop

#scores
function main:settings/stats/attack_speed/calculation {"max":0}
scoreboard players set @s shift_special_1 0
execute as @s[tag=upgrade_5,scores={rc_duration_t=1..}] run function main:characters/knight/rc/id1/release

#shield restore
function main:mechanics/healing/shield with storage minecraft:shift_shield_healing knight.id1

#damage
execute at @s anchored eyes run function main:mechanics/interaction/weapon/attack/start {"id":id1,"hitbox_type":'"follow",',"hitbox_duration":10,"sound_1":"entity.player.attack.sweep master @s ~ ~ ~ 3 0","sound_2":"item.trident.throw master @s ~ ~ ~ 3 0","character":knight,"type":shift,"particle":"dust{color:[1,1,0],scale:0.75}","x":3,"y":2,"z":4}

#vfx
function main:mechanics/effects/screenshake/start {duration:10,strength:10}

execute at @s anchored eyes positioned ^ ^ ^0.75 run function main:particles/white_circle
#sfx
execute at @s run playsound entity.generic.explode master @a ~ ~ ~ 3 1
execute at @s run playsound block.beacon.activate master @a ~ ~ ~ 3 1