execute at @a run function animated_java:forest_witch/summon {args:{}}
summon zombie ~ ~ ~ {Silent:1b,Tags:["id23_mob","enemy","newborn","boss","heavy"],active_effects:[{id:invisibility,duration:9999,amplifier:1,show_particles:false},{id:mining_fatigue,duration:9999,amplifier:1,show_particles:false}],ArmorItems:[{},{},{},{id:"minecraft:stone_button",count:1,components:{"minecraft:item_model":"minecraft:blank"}}],attributes:[{id:"minecraft:step_height",base:1},{id:"minecraft:follow_range",base:50},{id:"minecraft:attack_damage",base:0},{id:"minecraft:movement_speed",base:0.23},{id:"minecraft:scale",base:1.5},{id:"minecraft:knockback_resistance",base:1.0},{id:"minecraft:armor",base:1000.0}],Health:10000.0f,CustomName:'{"text":"Laura The Forest Witch","color":"red"}',Invulnerable:1b,Passengers:[{id:marker,Tags:["id23_mob"]}]}
# summon armor_stand ~ ~ ~ {Tags:["id23_ai"]}

particle flame ~ ~ ~ 0.5 0.5 0.5 0 25 force

#set id for stuff
scoreboard players set @e[type=zombie,tag=id23_mob,tag=newborn,limit=1] id 23

##set level, health and id for newborn enemy
#set health
scoreboard players set @e[type=zombie,tag=id23_mob,tag=newborn,limit=1] health_max 8000
scoreboard players add @e[type=zombie,tag=id23_mob,tag=newborn,limit=1] health 8000

execute as @e[type=zombie,tag=id23_mob,tag=newborn] run function main:game/mobs/spawn/scores

#enemy is not newborn now
tag @e[type=zombie,tag=id23_mob,tag=newborn,limit=1] remove newborn

#scores
scoreboard players set .cooldown boss 0
scoreboard players set .cooldown_attack boss 0
scoreboard players set .cooldown_throw boss 0
scoreboard players set .cooldown_teleport boss 0

scoreboard players set .attack_count boss 0
scoreboard players set .choice boss 0
scoreboard players set .attack_is_playing boss 0
scoreboard players set .stop boss 0
scoreboard players set .stun boss 0
scoreboard players set .stage boss 0

execute as @e[type=item_display,tag=aj.forest_witch.root] run function animated_java:forest_witch/animations/idle/tween {to_frame:0,duration:1}

#dialogs
function main:dialog/id/boss/forest_witch/check

execute if score .dialog_array_size dialog matches -1 as @e[type=item_display,tag=aj.forest_witch.root] run function main:game/mobs/ai/id/id23/spawn_azar

scoreboard players set .azar_no_kill progression 1