execute as @a run function main:mechanics/effects/screenshake/start {duration:10,strength:400}
tag @s remove ground_pound

execute at @s run particle item{item:sand} ~ ~ ~ 3 0 3 0 200 force
execute at @s run particle explosion_emitter ~ ~ ~ 3 0 3 0 1 force
execute at @s run playsound entity.lightning_bolt.impact master @a ~ ~ ~ 3 1
execute at @s run playsound entity.slime.attack master @a ~ ~ ~ 3 0.1
execute at @s rotated ~ 90 run function main:particles/circle {"particle":"cloud",range:0.0000005}
execute at @s rotated ~ 90 run function main:particles/circle {"particle":"cloud",range:0.0000004}
execute at @s rotated ~ 90 run function main:particles/circle {"particle":"campfire_cosy_smoke",range:0.0000003}

scoreboard players set .size particle_animation 10
execute at @s positioned ~ ~ ~ rotated 0 0 run function main:circle_regular {"particle":"poof"}

execute at @s positioned ~-5 ~-5 ~-5 as @e[type=#main:not_enemies,tag=ally,dx=9,dz=9,dy=9] run function main:mechanics/damage/player/damage {"damage":200,"id":id13,"id_number":13}

execute if score .difficulty_level progression matches 3..4 as @n[type=zombie,tag=id13_mob] at @s run function main:game/mobs/ai/id/id13/ground_pound/shoot
execute if score .difficulty_level progression matches 5.. as @n[type=zombie,tag=id13_mob] at @s run function main:game/mobs/ai/id/id13/ground_pound/shoot_1

execute if score .difficulty_level progression matches ..2 as @e[type=armor_stand,tag=spike] at @s run function main:game/wave/stages/2/trap_1 {"time":50}
execute if score .difficulty_level progression matches 3.. as @e[type=armor_stand,tag=spike] at @s run function main:game/wave/stages/2/trap_1 {"time":100}
function main:mechanics/particles/start {"start":"^ ^ ^","id":crack_particle,"character":none,"type":none,"transformation":",transformation:[12.0000f,0.0000f,0.0000f,0.0000f,0.0000f,0.0000f,-0.1000f,0.0000f,0.0000f,12.0000f,0.0000f,0.0000f,0.0000f,0.0000f,0.0000f,1.0000f]","frames":15}
#execute at @a positioned ~-10 ~-10 ~-10 as @e[type=armor_stand,tag=spike,dx=19,dy=19,dz=19] at @s run function main:game/arena/stages/2/trap