$scoreboard players remove .mana sorcerer $(mana)
scoreboard players add .e_l_cost sorcerer 20
scoreboard players remove .w_e_cost sorcerer 20
scoreboard players remove .w_l_cost sorcerer 20
scoreboard players remove .l_l_cost sorcerer 20
scoreboard players remove .w_w_cost sorcerer 20
scoreboard players remove .e_e_cost sorcerer 20
data modify storage sorcerer last set value "e_l"

function main:mechanics/effects/screenshake/start {duration:10,strength:10}

tag @e[type=#main:enemies,tag=enemy,tag=sorcerer_rc_e_l_hit] remove sorcerer_rc_e_l_hit

function main:mechanics/damage/enemy/calculation {"id":id1_e_l,"character":sorcerer,"type":"rc","damage":35,"stat":"MTC","local_bonus":0,"indicator":5}

execute at @s positioned ~-5.5 ~-5.5 ~-5.5 as @e[type=#main:enemies,tag=enemy,dx=10,dy=10,dz=10] run function main:characters/sorcerer/rc/id1/spells/e_l/hit

#vfx + sfx
execute at @s run function main:particles/land
execute at @s positioned ~ ~0.25 ~ rotated 0 90 run function main:particles/circle {"particle":"cloud",range:0.000001}

execute at @s run particle block{block_state:dirt} ~ ~-1 ~ 2 0 2 0 15 normal
execute at @s run playsound entity.player.attack.knockback master @a ~ ~ ~ 5 0
execute at @s run playsound entity.generic.explode master @a ~ ~ ~ 5 0
execute at @s run particle lava ~ ~1 ~ 1 0.1 1 0 50 normal
execute at @s run playsound entity.ender_dragon.growl master @a ~ ~ ~ 3 1
execute at @s run playsound atmos:punch_1 master @a ~ ~ ~ 5 0
execute at @s run playsound item.totem.use master @a ~ ~ ~ 5 0
playsound entity.firework_rocket.twinkle master @a ~ ~ ~ 5 0

$execute unless score .0 number matches $(mana) run function main:characters/sorcerer/rc/id1/spells/clear