execute if entity @s[tag=!upgrade_7] run function main:settings/stats/cooldown/calculation {"cooldown":6,"type":q}
execute if entity @s[tag=upgrade_7] run function main:settings/stats/cooldown/calculation {"cooldown":3,"type":q}

function main:characters/brawler/combust

scoreboard players set .weapon_animation brawler 0
scoreboard players set .rc_animation brawler 0
scoreboard players set .shift_animation brawler 0
scoreboard players set .q_animation brawler 8
function main:mechanics/animation/start {"frames":131,"start":"121"}

playsound item.firecharge.use master @a ~ ~ ~ 2 2
playsound block.chain.place master @a ~ ~ ~ 2 0
playsound item.trident.throw master @a ~ ~ ~ 2 0
playsound atmos:chain_1 master @a ~ ~ ~ 2 2

tag @e[type=#main:enemies,tag=enemy,tag=brawler_q_hit] remove brawler_q_hit
scoreboard players set .q_duration brawler 0
execute if entity @s[tag=upgrade_5] run scoreboard players set .upgrade_5 brawler 1

function main:mechanics/damage/enemy/calculation {"id":id1,"character":brawler,"type":"q","damage":25,"stat":"attack","local_bonus":0,"indicator":2}
execute if entity @s[tag=upgrade_7] run function main:characters/brawler/upgrades/id/7/damage

execute at @s anchored eyes run function main:mechanics/projectile/projectile_item_display {"id":id1,"character":brawler,"type":q,"distance":200,"texture":"weapons/brawler/brawler_q","size":"2f,2f,2f","translation":"0f,0f,0f","x":"~","y":"~","angle_1":"~","angle_2":"~","pierce":100,"spin":',"spin"',"rotation":"-1","tags":"","position":""}