function main:mechanics/effects/screenshake/start {duration:3,strength:200}

scoreboard players set .normals brawler 0
tag @s remove brawler_weapon

effect clear @s[scores={shift_duration_t=1..}] slow_falling
function main:settings/stats/attack_speed/calculation {"max":5}
scoreboard players set @s weapon_combo_reset 25

function main:mechanics/damage/enemy/calculation {"id":id1,"character":brawler,"type":"weapon","damage":50,"stat":"attack","local_bonus":0,"indicator":10}

execute if score .combustion brawler matches 1.. at @s run playsound entity.firework_rocket.twinkle master @a ~ ~ ~ 0.25 2

#hitbox
execute at @s anchored eyes run function main:mechanics/interaction/weapon/attack/start {"id":id1,"hitbox_duration":5,"sound_1":"block.piston.extend master @s ~ ~ ~ 3 0.5","sound_2":"item.firecharge.use master @s ~ ~ ~ 3 0.5","character":brawler,"type":weapon,"particle":"dust{color:[1,0,0],scale:0.75}","x":3,"y":3,"z":4}
playsound atmos:punch_2 master @a ~ ~ ~ 10 0.7 1
#particles
execute if score .combustion brawler matches ..0 at @s anchored eyes run function main:mechanics/particles/start {"start":"^ ^ ^","id":id1_2,"character":brawler,"type":weapon,"transformation":",transformation:[-3.4641f,-0.0068f,-0.0500f,-0.5625f,2.0000f,-0.0117f,-0.0866f,0.2500f,-0.0000f,-4.0000f,0.0003f,-1.0000f,0.0000f,0.0000f,0.0000f,1.0000f]","frames":8}
execute if score .combustion brawler matches 1.. at @s anchored eyes run function main:mechanics/particles/start {"start":"^ ^ ^","id":id1_1,"character":brawler,"type":weapon,"transformation":",transformation:[-3.4641f,-0.0068f,-0.0500f,-0.5625f,2.0000f,-0.0117f,-0.0866f,0.2500f,-0.0000f,-4.0000f,0.0003f,-1.0000f,0.0000f,0.0000f,0.0000f,1.0000f]","frames":8}

#tag
tag @s add brawler_weapon

scoreboard players set .weapon_animation brawler 12
function main:mechanics/animation/start {"frames":131,"start":"0"}