execute at @a run function animated_java:last_gladiator/summon {args:{}}
summon zombie ~ ~ ~ {Silent:1b,Tags:["id13_mob","enemy","newborn","boss","heavy"],active_effects:[{id:invisibility,duration:9999,amplifier:1,show_particles:false},{id:mining_fatigue,duration:9999,amplifier:1,show_particles:false}],ArmorItems:[{},{},{},{id:"minecraft:stone_button",count:1,components:{"minecraft:item_model":"minecraft:blank"}}],attributes:[{id:"minecraft:step_height",base:1},{id:"minecraft:follow_range",base:50},{id:"minecraft:attack_damage",base:0},{id:"minecraft:movement_speed",base:0.45},{id:"minecraft:scale",base:1.9},{id:"minecraft:knockback_resistance",base:1.0},{id:"minecraft:armor",base:1000.0}],Health:10000.0f,CustomName:'{"text":"Arthen The Last Gladiator","color":"red"}',Invulnerable:1b}
# summon armor_stand ~ ~ ~ {Tags:["id13_ai"]}

particle block{block_state:sand} ~ ~ ~ 0.25 0.25 0.25 0 5 force



#set id for stuff
scoreboard players set @e[type=zombie,tag=id13_mob,tag=newborn,limit=1] id 12

##set level, health and id for newborn enemy
#set health
scoreboard players set @e[type=zombie,tag=id13_mob,tag=newborn,limit=1] health_max 11000
scoreboard players add @e[type=zombie,tag=id13_mob,tag=newborn,limit=1] health 11000

execute as @e[type=zombie,tag=id13_mob,tag=newborn] run function main:game/mobs/spawn/scores

#enemy is not newborn now
tag @e[type=zombie,tag=id13_mob,tag=newborn,limit=1] remove newborn

#scores
scoreboard players set .cooldown boss 0
scoreboard players set .cooldown_attack_string boss 0
scoreboard players set .cooldown_run boss 0
scoreboard players set .cooldown_ground_pound boss 0
scoreboard players set .cooldown_jump_attack boss 0
scoreboard players set .cooldown_throw boss 0
scoreboard players set .duration_run boss 0
scoreboard players set .choice boss 0
scoreboard players set .attack_is_playing boss 0
scoreboard players set .stop boss 0
scoreboard players set .stun boss 0
scoreboard players set .stage boss 0

execute as @e[type=item_display,tag=aj.last_gladiator.root] run function animated_java:last_gladiator/animations/spawn/tween {to_frame:0,duration:5}

#dialogs
function main:dialog/id/boss/last_gladiator/check